Mathematical Functions
This category contains the Mathematical functions for Calc. To open the Function Wizard, choose Insert - Function.
ABS
Returns the absolute value of a number.
Syntax:
ABS(Number)
Number is the value whose absolute value is to be calculated.
Example:
Entering the value -56 will return an absolute value of 56.
Entering the value 56 will return an absolute value of 56.
ACOS
Returns the inverse trigonometric cosine of a number.
Syntax:
ACOS(Number)
Number is the value, whose inverse trigonometric cosine value is to be calculated.
Example:
The inverse trigonometric cosine of -1 returns the value 3.14.
ACOSH
Returns the inverse hyperbolic cosine of a number.
Syntax:
ACOSH(Number)
Number is the value whose inverse hyperbolic cosine is to be calculated.
Example:
The inverse hyperbolic cosine of 1 returns the value 0.
ACOT
Returns the inverse cotangent of the given number.
Syntax:
ACOT(Number)
Number is the value whose inverse cotangent is to be calculated.
Example:
The inverse cotangent of -1 returns the value 2.36.
ACOTH
Returns the inverse hyperbolic cotangent of the given number.
Syntax:
ACOTH(Number)
Number is the value whose inverse hyperbolic cotangent is to be calculated.
Example:
The inverse hyperbolic cotangent of 1.1 returns the value 1.52.
ASIN
Returns the inverse trigonometric sine of a number.
Syntax:
ASIN (Number)
Number is the value whose inverse trigonometric sine is to be calculated.
Example:
The inverse trigonometric sine of -1 returns the value -1.57.
ASINH
Returns the inverse hyperbolic sine of a number.
Syntax:
ASINH(Number)
Number is the value whose inverse hyperbolic sine is to be calculated.
Example:
The inverse hyperbolic sine of -90 returns the value -5.19.
ATAN
Returns the inverse trigonometric tangent of a number.
Syntax:
ATAN(Number)
Number is the value whose inverse trigonometric tangent value is to be calculated.
Example:
The inverse trigonometric tangent of -1 returns the value -0.79.
ATAN2
Returns the inverse trigonometric tangent of the specified x and y coordinates.
Syntax:
ATAN2(Number x; number y)
Number x is the value for the x coordinate.
Number y is the value for the y coordinate.
Example:
Entering the value 45 for the x coordinate and the value 90 for the y coordinate will return an inverse trigonometric tangent of 1.11.
ATANH
Returns the inverse hyperbolic tangent of a number.
Syntax:
ATANH(Number)
Number is the value whose inverse hyperbolic tangent is to be calculated.
Example:
The inverse hyperbolic tangent of 0.99 returns the value 2.65.
CEILING
Rounds a number up to the nearest multiple of Significance.
Syntax:
CEILING(Number; Significance; Mode)
Number is the number that is to be rounded up.
Significance is the number to whose multiple the value is to be rounded up.
Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number. This parameter is ignored when exporting to MS Excel as Excel does not know any third parameter.
 | If both parameters Number and Significance are negative and the Mode value is equal to zero or is not given, the results in OpenOffice.org and Excel will differ after the import has been completed. If you export the spreadsheet to Excel, use Mode=1 to see the same results in Excel as in Calc. |
Example:
=CEILING( -11; -2) returns -10
=CEILING( -11; -2; 0) returns -10
=CEILING( -11; -2; 1) returns -12
COMBIN
Returns the number of combinations for a given number of objects.
Syntax:
COMBIN(count 1; count 2)
Count 1 is the total number of elements.
Count 2 is the select count from the elements.
Example:
If you enter 2 in text boxes Count 1 and 2, 1 will be returned as the result.
COMBINA
Returns the number of combinations for a given number of objects (repetition included).
Syntax:
COMBINA(count 1; count 2)
Count 1 is the total number of elements.
Count 2 is the select count from the elements.
Example:
If you enter 2 in text boxes Count 1 and 2, 3 will be returned as the result.
CONVERT
This function allows you to convert a European currency value into Euros.
Syntax:
CONVERT(value;"Text"; "Text")
Value is the amount in the currency to be converted.
Text is the official abbreviation for the currency in question (for example, "EUR"). The first Text parameter gives the source value to be converted, the second Text parameter gives the destination value.
Example:
=CONVERT(100;"ATS";"EUR") converts 100 Austrian Schilling into Euro.
=CONVERT(100;"EUR";"DEM") converts 100 Euro into German Mark.
The table shows you the names of the currencies and the rates of exchange with the Euro set by the European Commission. The basis of calculation is 1 Euro.
|
"EUR" |
"ATS" |
13.7603 |
Austrian Schilling |
|
"EUR" |
"BEF" |
40.3399 |
Belgian Franc |
|
"EUR" |
"DEM" |
1.95583 |
German Mark |
|
"EUR" |
"ESP" |
166.386 |
Spanish Peseta |
|
"EUR" |
"FIM" |
5.94573 |
Finnish Markka |
|
"EUR" |
"FRF" |
6.55957 |
French Franc |
|
"EUR" |
"IEP" |
0.787564 |
Irish Pound |
|
"EUR" |
"ITL" |
1936.27 |
Italian Lira |
|
"EUR" |
"LUF" |
40.3399 |
Luxembourg Franc |
|
"EUR" |
"NLG" |
2.20371 |
Dutch Guilder |
|
"EUR" |
"PTE" |
200.482 |
Portuguese Escudo |
|
"EUR" |
"GRD" |
340.750 |
Greek Drachma |
COS
Returns the cosine of the given number (angle).
Syntax:
COS(Number)
Number is the value whose cosine is to be calculated.
Example:
The angle 6.28 (2Pi) returns a cosine of 1.
The angle 3.14 (Pi) returns a cosine of -1.
The angle 1.57 (Pi/2) returns a cosine of 0.
COSH
Returns the hyperbolic cosine of a number.
Syntax:
COSH(Number)
Number is the value whose hyperbolic cosine is to be calculated.
Example:
Entering the value -5 will return a hyperbolic cosine of 74.21.
COT
Returns the cotangent of the given angle.
Syntax:
COT(Number)
Number is the value whose cotangent is to be calculated.
Example:
The angle -45 returns a cotangent of -0.62.
The angle 90 returns a cotangent of -0.5.
COTH
Returns the hyperbolic cotangent of a given number (angle).
Syntax:
COTH(Number)
Number is the value whose hyperbolic cotangent is to be calculated.
Example:
Entering the value 90 returns a hyperbolic cotangent of 1.
COUNTBLANK
Returns the number of empty cells. Enter the cell references separated by a colon in the range text field.
Syntax:
COUNTBLANK(range)
range is the cell range in which the empty cells are counted.
Example:
Entering = COUNTBLANK (A1:C3) in an empty cell range results in 9.
COUNTIF
Returns the number of elements that meet with certain criteria within a cell range.
Syntax:
COUNTIF(range; criteria)
Range is the range to which the criteria are to be applied.
Criteria indicates the criteria in the form of a number, an expression or a character string. These criteria determine which cells are counted. You may also enter a search text in the form of a regular expression, e.g. "b.*" for all words that begin with b. You may also indicate a cell range that contains the search criterion. If you search for literal text, enclose the text in double quotes.
Example:
An example can be found under SUM().
DEGREES
Converts radians into degrees.
Syntax:
DEG(Number)
Number is the value to be converted.
EVEN
Rounds a positive number up to the nearest even integer and a negative number down to the nearest even integer.
Syntax:
EVEN(number)
Number is the number that is to be rounded.
Example:
If you enter the number 0.01, 2 will be returned as the result.
If you enter the number -2.1, -4 will be returned as the result.
If you enter the number 17.9, 18 will be returned as the result.
EXP
Returns e raised to the power of a number. The constant e has a value of approximately 2.71828182845904.
Syntax:
EXP(number)
Number is the power to which e is to be raised.
Example:
The result for e raised to the power -4 is 0.02.
FACT
Returns the factorial of a number. FACT(0) returns 1. FACT(n) returns 1*2*3*4* ... *n.
Syntax:
FACT(number)
Number is the value whose factorial is to be calculated.
Example:
FACT(0) by definition returns 1.
FACT(10) returns 3628800.
FLOOR
Rounds a number down to the nearest multiple of Significance.
Syntax:
FLOOR(Number; Significance; Mode)
Number is the number that is to be rounded down.
Significance is the value to whose multiple the number is to be rounded down.
Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of the number. This parameter is ignored when exporting to MS Excel as Excel does not know any third parameter.
| If both parameters Number and Significance are negative, and if the Mode value is equal to zero or is not specified, then the results in OpenOffice.org Calc and Excel will differ after exporting. If you export the spreadsheet to Excel, use Mode=1 to see the same results in Excel as in Calc. |
Example:
=FLOOR( -11; -2) returns -12
=FLOOR( -11; -2; 0) returns -12
=FLOOR( -11; -2; 1) returns -10
GCD
Returns the greatest common divisor of two or more integers.
Syntax:
GCD(integer 1 to 30)
Integer 1 to 30 are up to 30 integers whose greatest common divisor is to be calculated.
Example:
If you enter the numbers 512;1024 and 2000 in text boxes Integer 1;2 and 3, 16 will be returned as the result.
GCD_ADD
The result is the greatest common divisor of a list of numbers.
 | The functions whose names end with _ADD return the same results as the corresponding Microsoft Excel functions. Use the functions without _ADD to get results based on international standards. For example, the WEEKNUM function calculates the week number of a given date based on international standard ISO 6801, while WEEKNUM_ADD returns the same week number as Microsoft Excel. |
Syntax
GCD_ADD(Number(s))
Number(s): a list of up to 30 numbers.
Example
=GCD_ADD(5;15;25) returns 5.
INT
Rounds a number down to the nearest integer.
Syntax:
INT(number)
Number is the number that is to be rounded down to the nearest integer.
Example:
If you enter the number -0.1, -1 will be returned as the result.
If you enter the number 23.74, 23 will be returned as the result.
ISEVEN
Returns TRUE if the value is an even integer, or FALSE if the value is odd.
Syntax:
ISEVEN(value)
Value is the value to be checked.
Example:
If you enter the value 642, TRUE will be returned as the result.
If you enter the value -4, TRUE will be returned as the result.
If you enter the value 7.6, FALSE will be returned as the result.
ISODD
Returns TRUE if the value is odd, or FALSE if the number is even.
Syntax:
ISODD(value)
Value is the value to be checked.
Example:
If you enter the value 642, FALSE will be returned as the result.
If you enter the value -4, FALSE will be returned as the result.
If you enter the value 7.6, TRUE will be returned as the result.
LCM
Returns the least common multiple of one or more integers.
Syntax:
LCM(integer 1 to 30)
Integer 1 to 30 are up to 30 integers whose lowest common multiple is to be calculated.
Example:
If you enter the numbers 512;1024 and 2000 in the Integer 1;2 and 3 text boxes, 128000 will be returned as the result.
LCM_ADD
The result is the lowest common multiple of a list of numbers.
| The functions whose names end with _ADD return the same results as the corresponding Microsoft Excel functions. Use the functions without _ADD to get results based on international standards. For example, the WEEKNUM function calculates the week number of a given date based on international standard ISO 6801, while WEEKNUM_ADD returns the same week number as Microsoft Excel. |
Syntax
LCM_ADD (Number(s))
Number(s): a list of up to 30 numbers.
Example
=LCM_ADD(5;15;25) returns 75.
LN
Returns the natural logarithm based on the constant e of a number. The constant e has a value of approximately 2.71828182845904.
Syntax:
LN(number)
Number is the value whose natural logarithm is to be calculated.
Example:
The natural logarithm to the base e of the value 3 will return the rounded value of 1.1 as the result.
LOG
Returns the logarithm of a number to the specified base.
Syntax:
LOG(number; base)
Number is the value whose logarithm is to be calculated.
Base is the base for the logarithm calculation.
Example:
The logarithm of the number 10 to the base 3 will return 2.1 as the result.
The logarithm of the number 2.1 to the base 7 will return 0.38 as the result.
The logarithm of the number 0.75 to the base 7.5 will return -0.14 as the result.
LOG10
Returns the base-10 logarithm of a number.
Syntax:
LOG10(number)
Number is the value whose logarithm to the base 10 is to be calculated.
Example:
The logarithm to the base 10 of the value 3 will return 0.48 as the result.
MOD
Returns the remainder after a number is divided by a divisor.
Syntax:
MOD(Dividend; Divisor)
Dividend is the value from which to find the remainder after dividing.
Divisor is the number by which to divide the specified value.
Example:
The value 17 in the Dividend field is to be divided by the divisor -1.4. -1.2 will be returned as the remainder.
The value -13 in the Dividend field is to be divided by the divisor -3.4. -2.8 will be returned as the remainder.
The value 2987 in the Dividend field is to be divided by the divisor 362. 91 will be returned as the remainder.
MROUND
The result is the nearest integer multiple of the number.
Syntax
MROUND(Number; Multiple)
Example
Which integer multiple of 3 is the number 15.5 closest to?
=MROUND(15.5; 3) returns 15.
=MROUND(1.6;0.5) returns 1.5, the nearest integer multiple of 0.5 to approach 1.6.
MULTINOMIAL
Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.
Syntax
MULTINOMIAL (Number(s))
Number(s): a list of up to 30 numbers.
Example
=MULTINOMIAL(F11:H11) returns 1260, if F11 to H11 contain the values 2, 3 and 4. This corresponds to the formula =(2+3+4)! / (2!*3!*4!)
ODD
Rounds a positive number up to the nearest odd integer and a negative number down to the nearest odd integer.
Syntax:
ODD(number)
Number is the number that is to be rounded.
Example:
If you enter the number 1.01, 3 will be returned as the result.
If you enter the number -3.01, -5 will be returned as the result.
If you enter the number 17.9, 19 will be returned as the result.
PI
Returns the value of PI (rounded value 3.14159).
Syntax:
PI()
Example:
Pi is 3.14159... as a rounded value.
POWER
Returns the result of a number raised to a power.
Syntax:
POWER(base; power) or base ^ power
Base is the number that is to be raised to a given power.
Power is the exponent with which the base is to be raised to a power.
Example:
If you enter 3 as the base and -2 as the power, 0.11 will be returned as the result.
If you enter -3 as the base and -2 as the power, 0.11 will be returned as the result.
If you enter -3 as the base and 2 as the power, 9 will be returned as the result.
PRODUCT
Multiplies all the numbers given as arguments and returns the product.
Syntax:
PRODUCT(number 1 to 30)
Number 1 to number 30 are up to 30 arguments whose product is to be calculated.
Example:
If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 text boxes, 24 will be returned as the result.
QUOTIENT
Returns the integer result of a division operation.
Syntax
QUOTIENT(Numerator;Denominator)
Example
=QUOTIENT(11;3) returns 3. The remainder of 2 is omitted.
RADIANS
Converts degrees to radians.
Syntax:
RADIANS(number)
Number is the angle in degrees.
RAND
Returns a random number between 0 and 1.
Pull up a range in the table, start this function, select the Array field and click OK. The range you have selected will be filled with random numbers between 0 and 1.
Syntax:
RAND( )
RANDBETWEEN
Returns an integer random number between Bottom and Top (both inclusive). To recalculate press Shift+Ctrl+F9.
Syntax
RANDBETWEEN (Bottom; Top)
Example
=RANDBETWEEN (20;30) returns an integer of between 20 and 30.
ROUND
Returns a number rounded to a certain number of decimal places.
Syntax:
ROUND(number; count)
number is the number to be rounded.
count (optional) is the number of the places to which the value is to be rounded. If the count parameter is negative, numbers before the decimal are rounded.
Example:
If you enter the number 17.546 in the number field, with 1 specified as the number of rounding places, 17.5 will be returned as the result.
=ROUND(-32.4834; 3) returns -32.483. Change the cell format to see all decimals.
ROUNDDOWN
Rounds a number down, toward zero.
Syntax:
ROUNDDOWN(number; count)
number is the number to be rounded down.
count (optional) is the number of the places to which the value is to be rounded. If the count parameter is negative, numbers before the decimal are rounded.
Example:
Entering the value 567.567 and the value 2 in the count field will return 567.56.
ROUNDUP
Rounds a number up, according to the specified decimal place.
Syntax:
ROUNDUP(number; count)
number is the number to be rounded up.
count (optional) is the number of the places to which the value is to be rounded. If the count parameter is negative, numbers before the decimal are rounded.
Example:
Entering the value 123.343 and the value 2 in the count field will return the value 123.35.
SERIESSUM
Returns a sum of powers of the number x in accordance with the following formula:
SERIESSUM(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)
Syntax
SERIESSUM(x; n; m; coefficients)
x: the number as an independent variable
n: the starting power
m: the increment
coefficients: a series of coefficients. For each coefficient the series sum is extended by one section.
SIGN
Returns the sign of a number. The function returns the result 1 for a positive sign and -1 for a negative sign. If the number is zero, then the function likewise produces a zero.
Syntax:
SIGN(number)
Number is the number whose sign is to be determined.
Example:
If you enter the number 3.4, 1 will be returned as the result.
If you enter the number -4.5, -1 will be returned as the result.
SIN
Returns the sine of the given number (angle).
Syntax:
SIN(number)
Number is the angle in radians.
Example:
The sine of the angle (in radians) 3.14 (Pi) is 0.
The sine of the angle (in radians) 1.57 (Pi/2) is 1.
The sine of the angle (in radians) 0.79 (Pi/4) is 0.71.
SINH
Returns the hyperbolic sine of a number.
Syntax:
SINH(number)
Number is the number whose hyperbolic sine is to be calculated.
Example:
If you enter the value -5, -74.2 will be returned as the hyperbolic sine.
SQRT
Returns the positive square root of a number. The value of the number must be positive.
Syntax:
SQRT(number)
Number is the number whose square root is to be calculated.
Example:
The square root of 16 is 4.
The square root of the number -16 results in an error message.
SQRT(ABS(-16)) = 4.
SQRTPI
Returns the square root of a number*PI.
Syntax
SQRTPI (Number)
Example
=SQRTPI(2) returns the rounded value 2.506628.
SUBTOTAL
Calculates subtotals. If a range already contains subtotals, these are not used for further calculations. Use this function with the AutoFilters to take only the filtered records into account.
Syntax:
SUBTOTAL(function; range)
Function is a number that stands for one of the following functions:
|
Function index |
Function |
|
1 |
AVERAGE |
|
2 |
COUNT |
|
3 |
COUNTA |
|
4 |
MAX |
|
5 |
MIN |
|
6 |
PRODUCT |
|
7 |
STDEV |
|
8 |
STDEVP |
|
9 |
SUM |
|
10 |
VAR |
|
11 |
VARP |
Range is the range whose cells are included.
Example:
You have a table in the cell range A1:B5 containing cities in column A and accompanying figures in column B. You have used an AutoFilter so that you only see rows containing the city Hamburg. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:
=SUBTOTAL(9; B2:B5)
SUM
Adds all the numbers in a range of cells.
Syntax:
SUM(number1; number 2; ...; number 30)
Number 1 to number 30 are up to 30 arguments whose sum is to be calculated.
Example:
If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 text boxes, 9 will be returned as the result.
SUM(A1;A3;B5) calculates the sum of the three cells. SUM (A1:E10) calculates the sum of all cells in the A1 to E10 cell range.
Conditions linked by AND can be used with the function SUM() in the following manner:
Example assumption: You have entered invoices into a table. Column A contains the date value of the invoice, column B the amounts. You want to find a formula that you can use to return the total of all amounts only for a specific month, e.g. only the amount for the period >=1.1.99 to <1.2.99. The range with the date values covers A1:A40, the range containing the amounts to be totaled is B1:B40. C1 contains the start date, 1.1.99, of the invoices to be included and C2 the date, 1.2.99, that is no longer included.
Enter the following formula as an array formula:
=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)
In order to enter this as an array formula, you must press the Shift + Ctrl + Enter key instead of simply pressing the Enter key to close the formula. The formula will then be shown in the Formula bar enclosed in braces.
{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}
The formula is based on the fact that the result of a comparison is 1, if the criterion is met and 0 if it is not. The individual comparison results will be treated as an array and used in matrix multiplication, and at the end the individual values will be totaled to give the result matrix. The SUM() function can also be used in this way, for example, as COUNTIF() with several criteria.
SUMIF
Adds the cells specified by a given criteria. This function is used to browse a range when you search for a certain value.
Syntax:
SUMIF(range; criteria; sum_range)
Range is the range to which the criteria are to be applied.
Criteria is the cell in which the search criterion is shown, or the search criterion itself. If the criteria is written into the formula, it has to be surrounded by double quotes.
Sum_range is the range from which values are summed. If this parameter has not been indicated, the values found in the Range are summed.
Example:
To sum up only negative numbers: SUMIF(A1:A10;"<0")
SUMSQ
If you want to calculate the sum of the squares of numbers (totaling up of the squares of the arguments), enter these into the text fields.
Syntax:
SUMSQ(number 1 to 30)
Number 1 to number 30 are up to 30 arguments the sum of whose squares is to be calculated.
Example:
If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 text boxes, 29 is returned as the result.
TAN
Returns the tangent of the given angle.
Syntax:
TAN(number)
Number is the angle in radians.
Example:
The tangent of the angle (in radians) 3.14 (Pi) is 0.
The tangent of the angle (in radians) 0.79 (Pi/4) is 1.01.
The tangent of the angle (in radians) 0.39 (Pi/8) is 0.41.
TANH
Returns the hyperbolic tangent of a number.
Syntax:
TANH(number)
Number is the number whose hyperbolic tangent is to be calculated.
Example:
If you enter the value -5, the system returns the hyperbolic tangent -1.
If you enter the value 90, the system returns the hyperbolic tangent 1.
TRUNC
Truncates a number by removing decimal places of the number according to the precision specified in count.
| The visible decimal places are specified in Tools - Options - OpenOffice.org Calc - Calculate. |
Syntax:
TRUNC(number; count)
Number is the number whose decimal places are to be cut off.
Count is the number of places after the decimal delimiter that are not to be truncated.
Example:
If you enter the number 34.5678 and the count 1, 34.5 will be returned as the result.
Index
mathematical functions
Function Wizard, mathematical
functions, mathematical
trigonometric functions
ABS function
absolute values
values,absolute
COUNTBLANK function
counting,empty cells
empty cells,counting
ACOS function
ACOSH function
ACOT function
ACOTH function
ASIN function
ASINH function
ATAN function
ATAN2 function
ATANH function
COS function
COSH function
COT function
COTH function
DEGREES function
converting,radians, into degrees
EXP function
FACT function
factorials,numbers
INT function
numbers,rounding down to next integer
rounding,down to next integer
EVEN function
numbers,rounding up/down to even integers
rounding,up/down to even integers
GCD function
greatest common divisor
GCD_ADD function
ISEVEN function
even integers
ISODD function
odd integers
LCM function
least common multiples
lowest common multiples
LCM_ADD function
COMBIN function
number of combinations
COMBINA function
number of combinations with repetitions
TRUNC function
decimal places,cutting off
LN function
natural logarithm
LOG function
logarithms
LOG10 function
base-10 logarithm
CEILING function
rounding,up to multiples of significance
PI function
MULTINOMIAL function
POWER function
SERIESSUM function
PRODUCT function
numbers,multiplying
multiplying,numbers
SUMSQ function
square number additions
sums,of square numbers
MOD function
remainders of divisions
QUOTIENT function
divisions
RADIANS function
converting,degrees, into radians
ROUND function
ROUNDDOWN function
ROUNDUP function
SIN function
SINH function
SUM function
adding,numbers in cell ranges
SUMIF function
adding,specified numbers
TAN function
TANH function
AutoFilter function, subtotals
sums,of filtered data
filtered data, sums
SUBTOTAL function
Euro, converting in
CONVERT function
ODD function
rounding,up/down to nearest odd integer
FLOOR function
rounding,down to nearest multiple of significance
SIGN function
algebraic signs
MROUND function
nearest multiple
SQRT function
square roots,positive numbers
SQRTPI function
square roots,products of Pi
random numbers, between limits
RANDBETWEEN function
RAND function
random numbers,between 0 and 1
COUNTIF function
counting,specified cells
This help text is published from the OpenOffice-Help files under the Public Documentation License 1.0.
